plugins {
    id 'java'
    id 'com.gradleup.shadow' version '9.4.1'
}

group = 'tf.tuff'
version = '1.1.1'

java {
    sourceCompatibility = JavaVersion.VERSION_17
    targetCompatibility = JavaVersion.VERSION_17
}

tasks.withType(JavaCompile).configureEach {
    options.encoding = "UTF-8"
}

repositories {
    mavenCentral()
    maven { url = 'https://hub.spigotmc.org/nexus/content/repositories/snapshots/' }
    maven { url = 'https://repo.papermc.io/repository/maven-public/' }
    maven { url = 'https://repo.viaversion.com/everything/' }
    maven { url = 'https://repo.codemc.io/repository/maven-releases/' }
    maven { url = 'https://repo.codemc.io/repository/maven-snapshots/' }
    maven { url = 'https://jitpack.io' }
    maven { url = 'https://repo.dmulloy2.net/repository/public/' }
}

dependencies {
    compileOnly 'org.spigotmc:spigot-api:1.18.2-R0.1-SNAPSHOT'

    implementation 'com.github.retrooper:packetevents-spigot:2.13.0'

    compileOnly 'com.viaversion:viabackwards:5.9.1'
    compileOnly 'com.viaversion:viaversion:5.9.1'

    compileOnly 'it.unimi.dsi:fastutil:8.5.18'

    implementation 'com.fasterxml.jackson.core:jackson-databind:2.22.0'

    compileOnly 'io.netty:netty-all:4.2.15.Final'

    implementation 'org.java-websocket:Java-WebSocket:1.6.0'

    compileOnly 'org.projectlombok:lombok:1.18.46'
    annotationProcessor 'org.projectlombok:lombok:1.18.46'

    // Tests
    testImplementation 'com.github.seeseemelk:MockBukkit-v1.18:2.85.2'
    testImplementation 'org.junit.jupiter:junit-jupiter:5.11.0'
    testRuntimeOnly 'org.junit.jupiter:junit-jupiter-engine:5.11.0'
    testRuntimeOnly 'org.junit.platform:junit-platform-launcher:1.11.0'
    testRuntimeOnly 'org.spigotmc:spigot-api:1.18.2-R0.1-SNAPSHOT'
    testRuntimeOnly 'io.netty:netty-all:4.2.15.Final'
    testRuntimeOnly 'it.unimi.dsi:fastutil:8.5.18'
    testRuntimeOnly 'com.viaversion:viaversion:5.9.1'
    testRuntimeOnly 'com.viaversion:viabackwards:5.9.1'
}

processResources {
    filesMatching('plugin.yml') {
        expand(
            'version': project.version,
            'name': project.name
        )
    }
}

shadowJar {
    archiveClassifier.set('')
    archiveFileName.set("${project.name}-${project.version}.jar")

    relocate 'com.github.retrooper.packetevents', 'tf.tuff.packetevents'
    relocate 'io.github.retrooper.packetevents', 'tf.tuff.packetevents'
    relocate 'com.fasterxml.jackson', 'tf.tuff.jackson'
    relocate 'org.java_websocket', 'tf.tuff.websocket'

    exclude 'META-INF/*.SF'
    exclude 'META-INF/*.DSA'
    exclude 'META-INF/*.RSA'
    exclude 'META-INF/LICENSE'
    exclude 'META-INF/NOTICE'
    exclude 'META-INF/versions/**'
    exclude 'module-info.class'
}

tasks.named('jar') {
    enabled = false
}

tasks.named('build') {
    dependsOn shadowJar
}

test {
    useJUnitPlatform()
    testLogging {
        events "passed", "skipped", "failed"
        exceptionFormat = "full"
    }
}